6670 IF PNT < = TR THEN RETURN : REM UPDATED EXISTING INDEX
6680 TR = PNT:IP = PNT +1: GOSUB 6950: REM ADDED NEW INDEX
6690 RETURN
6700 REM ** RPTIDX ONERR RTN
6710 IF PEEK(222) < >6 THEN INVERSE : PRINT "ERROR # " PEEK(222)" IN LINE " PEEK(218) + PEEK(219) *256: NORMAL : END
6720 POKE 216,0
6730 HOME : VTAB 2: HTAB 5: PRINT F$"-RPTIDX FILE NOT FOUND !!": HTAB 5: PRINT "SHOULD WE CONTINUE ? (Y / N) ";: GET AN$: PRINT AN$: IF AN$ = "Y" THEN 6750
6740 PRINT CHR$(7): PRINT : HTAB 5: PRINT "USER ENDED AT LINE 6740": END
6750 GOSUB 6800:IP = 1: GOSUB 6950: GOTO 8270
6800 REM ** OPEN RPTIDX
6810 PRINT D$"OPEN"F$"-RPTIDX,L17"
6820 RETURN
6850 REM ** READ RPTIDX POINTER
6860 PRINT D$"READ"F$"-RPTIDX,R0"
6870 INPUT IP
6880 PRINT D$: RETURN
6900 REM ** WRITE RPTIDX DATA
6910 PRINT D$"WRITE"F$"-RPTIDX,R"IP
6920 PRINT ID$
6930 PRINT D$: RETURN
6950 REM ** WRITE RPTIDX POINTER
6960 PRINT D$"WRITE"F$"-RPTIDX,R0"
6970 PRINT IP
6980 PRINT D$: RETURN
7000 REM **OPEN DATA FILE**
7010 PRINT D$"OPEN"F$"-DATA,L"LGH +N
7020 RETURN
7100 REM **READ POINTER**
7110 PRINT D$"READ"F$"-DATA,R0"
7120 INPUT PNT
7130 PRINT D$: RETURN
7200 REM **READ DATA**
7210 PRINT D$"READ"F$"-DATA,R"PNT
7220 FOR R = 1 TO N
7230 INPUT O$(R,S)
7240 NEXT
7250 PRINT D$: RETURN
7300 REM **WRITE DATA**
7310 PRINT D$"WRITE"F$"-DATA,R"PNT
7320 FOR R = 1 TO N
7330 PRINT O$(R,S)
7340 NEXT
7350 PRINT D$: RETURN
7400 REM **WRITE POINTER**
7410 PRINT D$"WRITE"F$"-DATA,R0"
7420 PNT = PNT +CHG
7430 PRINT PNT
7440 PRINT D$: RETURN
7500 REM **CLOSE FILES**
7510 PRINT D$"CLOSE"
7520 RETURN
7600 REM **READ BALANCE**
7610 PRINT D$"OPEN"F$"-BAL"
7620 PRINT D$"READ"F$"-BAL"
7630 INPUT OC: INPUT OD: INPUT PC: INPUT PD
7640 INPUT BB: INPUT CB: INPUT DN: INPUT CN
7650 GOSUB 7500
7660 RETURN
7700 REM **WRITE BALANCE**
7710 PRINT D$"OPEN"F$"-BAL"
7720 PRINT D$"WRITE"F$"-BAL"
7730 PRINT OC: PRINT OD: PRINT PC: PRINT PD
7740 PRINT BB: PRINT CB: PRINT DN: PRINT CN
7750 GOSUB 7500
7760 RETURN
7800 REM **READ INDEX**
7810 B% = PNT/239
7820 DIM I$(T%(0,0),B% +2): IF PNT <2 THEN RETURN
7825 PRINT D$"OPEN"F$"-IDX"
7830 PRINT D$"READ"F$"-IDX"
7840 FOR I = 1 TO T%(0,0): FOR J = 0 TO B%
7850 INPUT I$(I,J):A$ = I$(I,J)
7860 IF ASC(A$) = 1 AND LEN(A$) = 1 THEN I$(I,J) = " ": GOTO 7880
7870 IF ASC(A$) = 1 THEN I$(I,J) = " " + RIGHT$(A$, LEN(A$) -1)
7880 NEXT : NEXT
7890 GOSUB 7500: RETURN
7900 REM **WRITE INDEX**
7910 GOSUB 7000: GOSUB 7100:B% = PNT/239
7920 IF PNT <2 THEN 7990
7925 PRINT D$"OPEN"F$"-IDX"
7930 PRINT D$"WRITE"F$"-IDX"
7940 FOR I = 1 TO T%(0,0): FOR J = 0 TO B%
7950 IF LEN(I$(I,J)) = 1 AND ASC(I$(I,J)) = 32 THEN I$(I,J) = CHR$(1): GOTO 7970
7960 IF ASC(I$(I,J)) = 32 THEN I$(I,J) = CHR$(1) + RIGHT$(I$(I,J), LEN(I$(I,J)) -1)
7970 PRINT I$(I,J)
7980 NEXT : NEXT
7990 GOSUB 7500: RETURN
8000 REM **INITIALIZE**
8010 DATA 8,CHECK-NUM,X,13,4,4,1,0,0,PAY-TO,X,10,6,30,2,0,0,MO,N,6,8,2,0,0,0,DAY,N,17,8,2,0,0,0,AMOUNT,$,10,10,8,0,0,0,POSTED,X,30,10,1,3,0,0,MAJ-CD,X,10,12,1,0,0,0,MIN-CD,X,23,12,1,0,0,0,49,3